' Kod uaktywnia protok DHCP dla okrelonego poczenia
' ------ KONFIGURACJA SKRYPTU ------
strComputer = "."
strConnection = "Poczenie lokalne"
' ------ KONIEC KONFIGURACJI ---------
set objWMI = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
set colNA = objWMI.ExecQuery("select * " & _
                             " from Win32_NetworkAdapter " & _
                             " where NetConnectionID = '" & strConnection & "'" ) 
for each objNA in colNA
   set colNAConfig = objWMI.ExecQuery _
      ("ASSOCIATORS OF {Win32_NetworkAdapter.DeviceID='" & _
        objNA.DeviceID & "'} " & _
      " WHERE resultClass = win32_NetworkAdapterConfiguration ")
   for each objNAConfig in colNAConfig
      if objNAConfig.DHCPEnabled = True then
         WScript.Echo "Protok DHCP uaktywniono ju dla " & strConnection
      else
         intRC = objNAConfig.EnableDHCP()
         if intRC = 0 then
            WScript.Echo "Protok DHCP uaktywniono dla " & strConnection
         elseif intRC = 1 then
            WScript.Echo "Konieczne jest przeadowanie systemu, aby zacz uywa protokou DHCP dla " & _
                         strConnection
         else
            WScript.Echo "Wystpi bd podczas uaktywniania protokou DHCP dla " & _
                         strconnection & ": " & intRC
         end if
      end if
   next
next
