' Kod dokonuje aktywacji systemu Windows Server 2003.
' ------ KONFIGURACJA SKRYPTU ------
strComputer = "."

boolActivateOnline = True  ' Jeli jest warto True, wartoci boolActivateOffline powinno
                           ' by False.

boolActivateOffline = False ' Jeli jest warto True, wartoci, boolActivateOnline powinno
                            ' by False.
strOfflineConfirmationCode = "1234-5678" ' W przypadku aktywacji przeprowadzanej w trybie offline 
                                         ' trzeba poda kod potwierdzajcy.
' ------ KONIEC KONFIGURACJI ---------
set objWMI = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
set colWPA = objWMI.InstancesOf("Win32_WindowsProductActivation")
for each objWPA in colWPA
   WScript.Echo "Ustawienia aktywacji:"
   Wscript.Echo "  Konieczno aktywacji: " & objWPA.ActivationRequired
   Wscript.Echo "  Nagwek: " & objWPA.Caption
   Wscript.Echo "  Opis: " & objWPA.Description
   Wscript.Echo "  Aktywno powiadamiania: " & objWPA.IsNotificationOn
   Wscript.Echo "  Identyfikator produktu: " & objWPA.ProductID
   Wscript.Echo "  Pozostay czas trwania okresu prbnego: " & objWPA.RemainingEvaluationPeriod
   Wscript.Echo "  Pozostay czas dopuszczalnego uywania systemu: " & objWPA.RemainingGracePeriod
   Wscript.Echo "  Nazwa serwera: " & objWPA.ServerName
   Wscript.Echo "  Identyfikator ustawie: " & objWPA.SettingID
   WScript.Echo

   if objWPA.ActivationRequired = True then
      if boolActivateOnline = True then
         intRC = objWPA.ActivateOnline
         if intRC <> 0 then
            WScript.Echo "Bd aktywacji w trybie online: " & intRC
         else
            WScript.Echo "Aktywacja w trybie online zakoczona powodzeniem."
         end if
      end if

      if boolActivateOffline = True then
         intRC = objWPA.ActivateOffline(strOfflineConfirmationCode)
         if intRC <> 0 then
            WScript.Echo "Bd aktywacji w trybie offline: " & intRC
         else
            WScript.Echo "Aktywacja w trybie offline zakoczona powodzeniem."
         end if
      end if
   end if
next
